mirror of
https://github.com/helix-editor/helix
synced 2024-11-10 10:34:45 +01:00
ec27d0707a
The test changes are needed because of the changes to comment parsing. The `1..36` to `1..37` change is because line comments now consume the newline.
82 lines
2.4 KiB
Scheme
82 lines
2.4 KiB
Scheme
([(line_comment !doc) (block_comment !doc)] @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
((doc_comment) @injection.content
|
|
(#set! injection.language "markdown")
|
|
(#set! injection.combined))
|
|
|
|
((macro_invocation
|
|
macro:
|
|
[
|
|
(scoped_identifier
|
|
name: (_) @_macro_name)
|
|
(identifier) @_macro_name
|
|
]
|
|
(token_tree) @injection.content)
|
|
(#eq? @_macro_name "html")
|
|
(#set! injection.language "html")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_invocation
|
|
macro:
|
|
[
|
|
(scoped_identifier
|
|
name: (_) @_macro_name)
|
|
(identifier) @_macro_name
|
|
]
|
|
(token_tree) @injection.content)
|
|
(#eq? @_macro_name "slint")
|
|
(#set! injection.language "slint")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_invocation
|
|
(token_tree) @injection.content)
|
|
(#set! injection.language "rust")
|
|
(#set! injection.include-children))
|
|
|
|
((macro_rule
|
|
(token_tree) @injection.content)
|
|
(#set! injection.language "rust")
|
|
(#set! injection.include-children))
|
|
|
|
(call_expression
|
|
function: (scoped_identifier
|
|
path: (identifier) @_regex (#eq? @_regex "Regex")
|
|
name: (identifier) @_new (#eq? @_new "new"))
|
|
arguments: (arguments (raw_string_literal) @injection.content)
|
|
(#set! injection.language "regex"))
|
|
|
|
(call_expression
|
|
function: (scoped_identifier
|
|
path: (scoped_identifier (identifier) @_regex (#eq? @_regex "Regex") .)
|
|
name: (identifier) @_new (#eq? @_new "new"))
|
|
arguments: (arguments (raw_string_literal) @injection.content)
|
|
(#set! injection.language "regex"))
|
|
|
|
; Highlight SQL in `sqlx::query!()`, `sqlx::query_scalar!()`, and `sqlx::query_scalar_unchecked!()`
|
|
(macro_invocation
|
|
macro: (scoped_identifier
|
|
path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
|
|
name: (identifier) @_query (#match? @_query "^query(_scalar|_scalar_unchecked)?$"))
|
|
(token_tree
|
|
; Only the first argument is SQL
|
|
.
|
|
[(string_literal) (raw_string_literal)] @injection.content
|
|
)
|
|
(#set! injection.language "sql"))
|
|
|
|
; Highlight SQL in `sqlx::query_as!()` and `sqlx::query_as_unchecked!()`
|
|
(macro_invocation
|
|
macro: (scoped_identifier
|
|
path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
|
|
name: (identifier) @_query_as (#match? @_query_as "^query_as(_unchecked)?$"))
|
|
(token_tree
|
|
; Only the second argument is SQL
|
|
.
|
|
; Allow anything as the first argument in case the user has lower case type
|
|
; names for some reason
|
|
(_)
|
|
[(string_literal) (raw_string_literal)] @injection.content
|
|
)
|
|
(#set! injection.language "sql"))
|