mirror of
https://github.com/helix-editor/helix
synced 2026-03-11 10:28:27 +01:00
97aee4950f
The dev-shell failed since the recent nixpkgs updates like so:
… while calling the 'derivationStrict' builtin
at <nix/derivation-internal.nix>:37:12:
36|
37| strict = derivationStrict drvAttrs;
| ^
38|
… while evaluating derivation 'nix-shell'
whose name attribute is located at /nix/store/9v6qa656sq3xc58vkxslqy646p0ajj61-source/pkgs/stdenv/generic/make-derivation.nix:544:13
… while evaluating attribute '__impureHostDeps' of derivation 'nix-shell'
at /nix/store/9v6qa656sq3xc58vkxslqy646p0ajj61-source/pkgs/stdenv/generic/make-derivation.nix:694:15:
693| );
694| __impureHostDeps =
| ^
695| computedImpureHostDeps
(stack trace truncated; use '--show-trace' to show the full, detailed trace)
error: darwin.apple_sdk_11_0 has been removed as it was a legacy compatibility stub; see <https://nixos.org/manual/nixpkgs/stable/#sec-darwin-legacy-frameworks> for migration instructions
According to the link, the CoreFoundation input has been a stub for a
while and we can remove it.
96 lines
2.8 KiB
Nix
96 lines
2.8 KiB
Nix
{
|
|
description = "A post-modern text editor.";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
|
|
rust-overlay = {
|
|
url = "github:oxalica/rust-overlay";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
};
|
|
|
|
outputs = {
|
|
self,
|
|
nixpkgs,
|
|
rust-overlay,
|
|
...
|
|
}: let
|
|
inherit (nixpkgs) lib;
|
|
eachSystem = lib.genAttrs lib.systems.flakeExposed;
|
|
pkgsFor = eachSystem (system:
|
|
import nixpkgs {
|
|
localSystem.system = system;
|
|
overlays = [(import rust-overlay) self.overlays.helix];
|
|
});
|
|
gitRev = self.rev or self.dirtyRev or null;
|
|
in {
|
|
packages = eachSystem (system: {
|
|
inherit (pkgsFor.${system}) helix;
|
|
/*
|
|
The default Helix build. Uses the latest stable Rust toolchain, and unstable
|
|
nixpkgs.
|
|
|
|
The build inputs can be overridden with the following:
|
|
|
|
packages.${system}.default.override { rustPlatform = newPlatform; };
|
|
|
|
Overriding a derivation attribute can be done as well:
|
|
|
|
packages.${system}.default.overrideAttrs { buildType = "debug"; };
|
|
*/
|
|
default = self.packages.${system}.helix;
|
|
});
|
|
checks =
|
|
lib.mapAttrs (system: pkgs: let
|
|
# Get Helix's MSRV toolchain to build with by default.
|
|
msrvToolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
|
|
msrvPlatform = pkgs.makeRustPlatform {
|
|
cargo = msrvToolchain;
|
|
rustc = msrvToolchain;
|
|
};
|
|
in {
|
|
helix = self.packages.${system}.helix.override {
|
|
rustPlatform = msrvPlatform;
|
|
};
|
|
})
|
|
pkgsFor;
|
|
|
|
# Devshell behavior is preserved.
|
|
devShells =
|
|
lib.mapAttrs (system: pkgs: {
|
|
default = let
|
|
commonRustFlagsEnv = "-C link-arg=-fuse-ld=lld -C target-cpu=native --cfg tokio_unstable";
|
|
platformRustFlagsEnv = lib.optionalString pkgs.stdenv.isLinux "-Clink-arg=-Wl,--no-rosegment";
|
|
in
|
|
pkgs.mkShell {
|
|
inputsFrom = [self.checks.${system}.helix];
|
|
nativeBuildInputs = with pkgs;
|
|
[
|
|
lld
|
|
cargo-flamegraph
|
|
rust-bin.nightly.latest.rust-analyzer
|
|
]
|
|
++ (lib.optional (stdenv.isx86_64 && stdenv.isLinux) cargo-tarpaulin)
|
|
++ (lib.optional stdenv.isLinux lldb);
|
|
shellHook = ''
|
|
export RUST_BACKTRACE="1"
|
|
export RUSTFLAGS="''${RUSTFLAGS:-""} ${commonRustFlagsEnv} ${platformRustFlagsEnv}"
|
|
'';
|
|
};
|
|
})
|
|
pkgsFor;
|
|
|
|
overlays = {
|
|
helix = final: prev: {
|
|
helix = final.callPackage ./default.nix {inherit gitRev;};
|
|
};
|
|
|
|
default = self.overlays.helix;
|
|
};
|
|
};
|
|
nixConfig = {
|
|
extra-substituters = ["https://helix.cachix.org"];
|
|
extra-trusted-public-keys = ["helix.cachix.org-1:ejp9KQpR1FBI2onstMQ34yogDm4OgU2ru6lIwPvuCVs="];
|
|
};
|
|
}
|