mirror of
git://git.code.sf.net/p/zsh/code
synced 2024-10-03 09:21:19 +02:00
49 lines
1.2 KiB
Plaintext
49 lines
1.2 KiB
Plaintext
#compdef -K _expand_alias complete-word \C-xa
|
|
|
|
local word expl tmp pre sel what
|
|
|
|
setopt localoptions ${_comp_options[@]}
|
|
|
|
if [[ -n $funcstack[2] ]]; then
|
|
if [[ "$funcstack[2]" = _prefix ]]; then
|
|
word="$IPREFIX$PREFIX$SUFFIX"
|
|
else
|
|
word="$IPREFIX$PREFIX$SUFFIX$ISUFFIX"
|
|
fi
|
|
pre=()
|
|
else
|
|
local curcontext="$curcontext"
|
|
|
|
if [[ -z "$curcontext" ]]; then
|
|
curcontext="expand-alias-word:::"
|
|
else
|
|
curcontext="expand-alias-word:${curcontext#*:}"
|
|
fi
|
|
|
|
word="$IPREFIX$PREFIX$SUFFIX$ISUFFIX"
|
|
pre=(_main_complete - aliases)
|
|
fi
|
|
|
|
zstyle -s ":completion:${curcontext}:" regular tmp || tmp=yes
|
|
case $tmp in
|
|
always) sel=r;;
|
|
yes|1|true|on) [[ CURRENT -eq 1 ]] && sel=r;;
|
|
esac
|
|
zstyle -T ":completion:${curcontext}:" global && sel="g$sel"
|
|
zstyle -t ":completion:${curcontext}:" disabled && sel="${sel}${(U)sel}"
|
|
|
|
tmp=
|
|
[[ $sel = *r* ]] && tmp=$aliases[$word]
|
|
[[ -z $tmp && $sel = *g* ]] && tmp=$galiases[$word]
|
|
[[ -z $tmp && $sel = *R* ]] && tmp=$dis_aliases[$word]
|
|
[[ -z $tmp && $sel = *G* ]] && tmp=$dis_galiases[$word]
|
|
|
|
if [[ -n $tmp ]]; then
|
|
$pre _wanted aliases expl alias compadd -UQ ${(Q)tmp%%[[:blank:]]##}
|
|
elif (( $#pre )) && zstyle -t ":completion:${curcontext}:" complete; then
|
|
$pre _aliases -s "$sel" -S ''
|
|
else
|
|
return 1
|
|
fi
|
|
|