mirror of
git://git.code.sf.net/p/zsh/code
synced 2024-10-03 09:21:19 +02:00
52 lines
1.4 KiB
Plaintext
52 lines
1.4 KiB
Plaintext
#compdef popd
|
|
|
|
# This just completes the numbers after +, showing the full directory list
|
|
# with numbers. For - we do the same thing, but reverse the numbering (other
|
|
# way round if pushdminus is set). Note that this function is also called
|
|
# from _cd for cd and pushd.
|
|
|
|
setopt localoptions nonomatch
|
|
|
|
local expl list lines revlines disp suf
|
|
|
|
if [[ "$SUFFIX" = */* ]]; then
|
|
ISUFFIX="/${SUFFIX#*/}$ISUFFIX"
|
|
SUFFIX="${SUFFIX%%/*}"
|
|
suf=(-S '')
|
|
else
|
|
suf=(-qS/)
|
|
fi
|
|
|
|
### we decided against this, for now...
|
|
#! zstyle -T ":completion:${curcontext}:directory-stack" prefix-needed ||
|
|
|
|
[[ $PREFIX = [-+]* ]] || return 1
|
|
|
|
if zstyle -T ":completion:${curcontext}:directory-stack" verbose; then
|
|
# get the list of directories with their canonical number
|
|
# and turn the lines into an array, removing the current directory
|
|
lines=("${dirstack[@]}")
|
|
|
|
if [[ ( $PREFIX[1] = - && ! -o pushdminus ) ||
|
|
( $PREFIX[1] = + && -o pushdminus ) ]]; then
|
|
integer i
|
|
revlines=( $lines )
|
|
for (( i = 1; i <= $#lines; i++ )); do
|
|
lines[$i]="$((i-1)) -- ${revlines[-$i]##[0-9]#[ ]#}"
|
|
done
|
|
else
|
|
for (( i = 1; i <= $#lines; i++ )); do
|
|
lines[$i]="$i -- ${lines[$i]##[0-9]#[ ]#}"
|
|
done
|
|
fi
|
|
# get the array of numbers only
|
|
list=( ${PREFIX[1]}${^lines%% *} )
|
|
disp=( -ld lines )
|
|
else
|
|
list=( ${PREFIX[1]}{0..${#dirstack}} )
|
|
disp=()
|
|
fi
|
|
|
|
_wanted -V directory-stack expl 'directory stack' \
|
|
compadd "$@" "$suf[@]" "$disp[@]" -Q -a list
|