mirror of
git://git.code.sf.net/p/zsh/code
synced 2024-11-20 05:53:52 +01:00
70 lines
1.5 KiB
Plaintext
70 lines
1.5 KiB
Plaintext
#autoload
|
|
|
|
# Generate all possible completions. Note that this is not intended as
|
|
# a normal completion function, but as one possible value for the
|
|
# completer style.
|
|
|
|
local comp name oldcontext ret=1
|
|
typeset -T curcontext="$curcontext" ccarray
|
|
|
|
oldcontext="$curcontext"
|
|
|
|
# If we have a user-supplied context name, use only that.
|
|
|
|
if [[ -n "$compcontext" ]]; then
|
|
ccarray[3]="$compcontext"
|
|
|
|
comp="$_comps[$compcontext]"
|
|
[[ -z "$comp" ]] || "$comp"
|
|
|
|
return
|
|
fi
|
|
|
|
# An entry for `-first-' is the replacement for `compctl -T'
|
|
|
|
comp="$_comps[-first-]"
|
|
if [[ ! -z "$comp" ]]; then
|
|
ccarray[3]=-first-
|
|
"$comp" && ret=0
|
|
if [[ "$_compskip" = all ]]; then
|
|
_compskip=
|
|
return ret
|
|
fi
|
|
fi
|
|
|
|
# If we are inside `vared' and we don't have a $compcontext, we treat
|
|
# this like a parameter assignment. Which it is.
|
|
|
|
[[ -n $compstate[vared] ]] && compstate[context]=vared
|
|
|
|
# For arguments and command names we use the `_normal' function.
|
|
|
|
if [[ "$compstate[context]" = command ]]; then
|
|
curcontext="$oldcontext"
|
|
_normal -s && ret=0
|
|
else
|
|
# Let's see if we have a special completion definition for the other
|
|
# possible contexts.
|
|
|
|
local cname="-${compstate[context]:s/_/-/}-"
|
|
|
|
ccarray[3]="$cname"
|
|
|
|
comp="$_comps[$cname]"
|
|
|
|
# If not, we use default completion, if any.
|
|
|
|
if [[ -z "$comp" ]]; then
|
|
if [[ "$_compskip" = *default* ]]; then
|
|
_compskip=
|
|
return 1
|
|
fi
|
|
comp="$_comps[-default-]"
|
|
fi
|
|
[[ -z "$comp" ]] || "$comp" && ret=0
|
|
fi
|
|
|
|
_compskip=
|
|
|
|
return ret
|