mirror/zsh
1
0
Fork 0
mirror of git://git.code.sf.net/p/zsh/code synced 2024-09-22 03:40:47 +02:00
Code

43166: new zathura completion

Browse Source
This commit is contained in:
Doron Behar 2018-07-13 22:52:59 +03:00 committed by Peter Stephenson
parent 73a3ad345c
commit 50e272d301
3 changed files with 54 additions and 1 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

5
ChangeLog
View File

@ -1,3 +1,8 @@
2018-07-17 Peter Stephenson <p.w.stephenson@ntlworld.com>
* Doron Behar: 43166: Completion/Unix/Type/_pspdf,
Completion/X/Command/_zathura: new zathura completion.
2018-07-18 Jun-ichi Takimoto <takimoto-j@kba.biglobe.ne.jp>
* 43177: Completion/Unix/Command/_grep: support bzgrep, and add

2
Completion/Unix/Type/_pspdf
View File

@ -1,4 +1,4 @@
#compdef gsbj gsdj gsdj500 gslj gslp gsnd ps2ascii ghostview mgv pstoedit pstotgif zathura
#compdef gsbj gsdj gsdj500 gslj gslp gsnd ps2ascii ghostview mgv pstoedit pstotgif
local expl ext

48
Completion/X/Command/_zathura Normal file
View File

@ -0,0 +1,48 @@
#compdef zathura
(( $+functions[_zathura_files] )) ||
_zathura_files(){
local -a plugins_files
local plugins_dir
for plugins_dir in \
${(Qv)opt_args[(i)-p|--plugins-dir]}(#qN) \
{/usr/local,/usr,}/lib/zathura(#qN)
do
plugins_files=( $plugins_dir/*.so )
(( $#plugins_files )) && break
done
if [[ -z "${plugins_files}" ]]; then
_files -g "*.pdf(-.)"
return
fi
local -a supported_filetypes
local pf
for pf in "${plugins_files[@]}"; do
if [[ $pf =~ "mupdf" ]]; then
supported_filetypes+="pdf"
supported_filetypes+="epub"
supported_filetypes+="xps"
elif [[ $pf =~ "poppler" ]]; then
supported_filetypes+="pdf"
else
supported_filetypes+="${${pf%.so}#${plugins_dir}/lib}"
fi
done
_files -g "*.(${(j.|.)supported_filetypes})(-.)"
}
_arguments -s -S \
{-e,--reparent=}'[specify xid of window to reparent to]:xid:_x_window' \
{-c,--config-dir=}'[specify path to the config directory]:config directory:{_files -/}' \
{-d,--data-dir=}'[specify path to the data directory]:data directory:{_files -/}' \
{-p,--plugins-dir=}'[specify path to the directory containing plugins]:plugins directory:{_files -/}' \
{-w,--password=}"[specify a password for the document]:password: " \
{-P,--page=}'[open the document at the given page number]:page number: ' \
{-l,--log-level=}'[set log level]:log level:(debug info warning error)' \
{-x,--synctex-editor-command=}'[specify synctex editor command]:synctex editor command:_cmdstring' \
'--synctex-forward=[jump to the given position]:synctex position: ' \
'--synctex-pid=[specify pid of an instance having the correct file opened]:synctex pid:_pids' \
'--fork[fork into background]' \
'(- :)--version[display version string and exit]' \
'(- :)--help[display help and exit]' \
'*:file:_zathura_files'