From 3ef3b9f2cf2e9808918727c4e484d9ba573770e2 Mon Sep 17 00:00:00 2001
From: Sven Wischnowsky <wischnow@users.sourceforge.net>
Date: Mon, 2 Apr 2001 11:53:59 +0000
Subject: [PATCH] moved from Completion/User/_init_d

---
 Completion/Unix/Command/_init_d | 23 +++++++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100644 Completion/Unix/Command/_init_d

diff --git a/Completion/Unix/Command/_init_d b/Completion/Unix/Command/_init_d
new file mode 100644
index 000000000..280b0a9af
--- /dev/null
+++ b/Completion/Unix/Command/_init_d
@@ -0,0 +1,23 @@
+#compdef -P */(init|rc[0-9S]#).d/*
+
+local magic cmds what
+
+# This should probably be system specific...
+
+# If the file starts with `#!' we hope that this is a shell script
+# and get lines looking like <space>foo|bar) with the words in $what.
+
+what='(st(art|op|atus)|(force-|)re(start|load)|debug_(up|down)|dump(|_stats)|add|delete|clean|list)'
+
+read -u0k 2 magic < $words[1] && [[ $magic = '#!' ]] &&
+    cmds=( ${${(j:|:s:|:)${(M)${(f)"$(< $words[1])"}:#[[:blank:]]#(\'|)${~what}(|${~what})#(\'|)\)}}//[^a-z_]} )
+
+# This would be the pattern to use every line of the form <space>foo).
+# Some people say this might match too many lines...
+#
+#    cmds=( ${${(j:|:s:|:)${(M)${(f)"$(< $words[1])"}:#[[:blank:]]#(\'|)[a-z_|]##(\'|)\)}}//[^a-z_]} )
+
+(( $#cmds )) || zstyle -a ":completion:${curcontext}:commands" commands cmds ||
+    cmds=(start stop)
+
+_sub_commands $cmds