zsh/Completion/User/_hosts

#compdef ftp ping rwho rup xping traceroute host

local expl hosts

if ! zstyle -a ":completion:${curcontext}:hosts" hosts hosts; then
  (( $+_cache_hosts )) ||
      : ${(A)_cache_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}}

  hosts=( "$_cache_hosts[@]" )
fi

_wanted hosts expl host \
    compadd -M 'm:{a-zA-Z}={A-Za-z} r:|.=* r:|=*' "$@" -a hosts
fix filename quoting in _zip and don't use _hosts for lftp 2001-03-12 10:34:03 +01:00			`#compdef ftp ping rwho rup xping traceroute host`
Initial revision 1999-04-15 20:05:38 +02:00
use compadd -[ak] (11549) 2000-05-31 11:38:25 +02:00			`local expl hosts`

			`if ! zstyle -a ":completion:${curcontext}:hosts" hosts hosts; then`
			`(( $+_cache_hosts )) \|\|`
			`: ${(A)_cache_hosts:=${(s: :)${(ps:\t:)${${(f)~~"$(</etc/hosts)"}%%\#*}##[:blank:]#[^[:blank:]]#}}}`

			`hosts=( "$_cache_hosts[@]" )`
			`fi`

			`_wanted hosts expl host \`
			`compadd -M 'm:{a-zA-Z}={A-Za-z} r:\|.=* r:\|=*' "$@" -a hosts`