mirror of
https://github.com/poseidon/typhoon
synced 2024-05-23 07:56:14 +02:00
e826b49648
* Fedora CoreOS stable (after Oct 6) ships separate initramfs
and rootfs images, used as initrd's
* Update profiles to match the Matchbox examples, which have
already switched to the new profile and to remove the unused
kernel args
* Requires Fedora CoreOS version which ships rootfs images
(e.g. stable 32.20200923.3.0 or later)
Rel:
* https://github.com/coreos/fedora-coreos-tracker/issues/390#issuecomment-661986987
* da0df01763 (diff-4541f7b7c174f6ae6270135942c1c65ed9e09ebe81239709f5a9fb34e858ddcf)
Supercedes https://github.com/poseidon/typhoon/pull/888
108 lines
4.2 KiB
HCL
108 lines
4.2 KiB
HCL
locals {
|
|
remote_kernel = "https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-kernel-x86_64"
|
|
remote_initrd = [
|
|
"https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-initramfs.x86_64.img",
|
|
"https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-rootfs.x86_64.img"
|
|
]
|
|
|
|
remote_args = [
|
|
"ip=dhcp",
|
|
"rd.neednet=1",
|
|
"coreos.inst.install_dev=${var.install_disk}",
|
|
"coreos.inst.ignition_url=${var.matchbox_http_endpoint}/ignition?uuid=$${uuid}&mac=$${mac:hexhyp}",
|
|
"coreos.inst.image_url=https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-metal.x86_64.raw.xz",
|
|
"console=tty0",
|
|
"console=ttyS0",
|
|
]
|
|
|
|
cached_kernel = "/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-kernel-x86_64"
|
|
cached_initrd = [
|
|
"/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-initramfs.x86_64.img",
|
|
"/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-rootfs.x86_64.img"
|
|
]
|
|
|
|
cached_args = [
|
|
"ip=dhcp",
|
|
"rd.neednet=1",
|
|
"coreos.inst.install_dev=${var.install_disk}",
|
|
"coreos.inst.ignition_url=${var.matchbox_http_endpoint}/ignition?uuid=$${uuid}&mac=$${mac:hexhyp}",
|
|
"coreos.inst.image_url=${var.matchbox_http_endpoint}/assets/fedora-coreos/fedora-coreos-${var.os_version}-metal.x86_64.raw.xz",
|
|
"console=tty0",
|
|
"console=ttyS0",
|
|
]
|
|
|
|
kernel = var.cached_install ? local.cached_kernel : local.remote_kernel
|
|
initrd = var.cached_install ? local.cached_initrd : local.remote_initrd
|
|
args = var.cached_install ? local.cached_args : local.remote_args
|
|
}
|
|
|
|
|
|
// Fedora CoreOS controller profile
|
|
resource "matchbox_profile" "controllers" {
|
|
count = length(var.controllers)
|
|
name = format("%s-controller-%s", var.cluster_name, var.controllers.*.name[count.index])
|
|
|
|
kernel = local.kernel
|
|
initrd = local.initrd
|
|
args = concat(local.args, var.kernel_args)
|
|
|
|
raw_ignition = data.ct_config.controller-ignitions.*.rendered[count.index]
|
|
}
|
|
|
|
data "ct_config" "controller-ignitions" {
|
|
count = length(var.controllers)
|
|
|
|
content = data.template_file.controller-configs.*.rendered[count.index]
|
|
strict = true
|
|
snippets = lookup(var.snippets, var.controllers.*.name[count.index], [])
|
|
}
|
|
|
|
data "template_file" "controller-configs" {
|
|
count = length(var.controllers)
|
|
|
|
template = file("${path.module}/fcc/controller.yaml")
|
|
vars = {
|
|
domain_name = var.controllers.*.domain[count.index]
|
|
etcd_name = var.controllers.*.name[count.index]
|
|
etcd_initial_cluster = join(",", formatlist("%s=https://%s:2380", var.controllers.*.name, var.controllers.*.domain))
|
|
cluster_dns_service_ip = module.bootstrap.cluster_dns_service_ip
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
}
|
|
}
|
|
|
|
// Fedora CoreOS worker profile
|
|
resource "matchbox_profile" "workers" {
|
|
count = length(var.workers)
|
|
name = format("%s-worker-%s", var.cluster_name, var.workers.*.name[count.index])
|
|
|
|
kernel = local.kernel
|
|
initrd = local.initrd
|
|
args = concat(local.args, var.kernel_args)
|
|
|
|
raw_ignition = data.ct_config.worker-ignitions.*.rendered[count.index]
|
|
}
|
|
|
|
data "ct_config" "worker-ignitions" {
|
|
count = length(var.workers)
|
|
|
|
content = data.template_file.worker-configs.*.rendered[count.index]
|
|
strict = true
|
|
snippets = lookup(var.snippets, var.workers.*.name[count.index], [])
|
|
}
|
|
|
|
data "template_file" "worker-configs" {
|
|
count = length(var.workers)
|
|
|
|
template = file("${path.module}/fcc/worker.yaml")
|
|
vars = {
|
|
domain_name = var.workers.*.domain[count.index]
|
|
cluster_dns_service_ip = module.bootstrap.cluster_dns_service_ip
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
node_labels = join(",", lookup(var.worker_node_labels, var.workers.*.name[count.index], []))
|
|
node_taints = join(",", lookup(var.worker_node_taints, var.workers.*.name[count.index], []))
|
|
}
|
|
}
|
|
|