mirror of
https://github.com/poseidon/typhoon
synced 2024-05-24 08:26:15 +02:00
fa8f68f50e
* A `aws_ami` data source will fail a Terraform plan if no matching AMI is found, even if the AMI is not used. ARM64 images are only published to a few US regions, so the `aws_ami` data query could fail when creating Fedora CoreOS AWS clusters in non-US regions * Condition `aws_ami` on whether experimental arch `arm64` is chosen * Recent regression introduced in v1.19.4 https://github.com/poseidon/typhoon/pull/875 Closes https://github.com/poseidon/typhoon/issues/886
88 lines
2.5 KiB
HCL
88 lines
2.5 KiB
HCL
# Discrete DNS records for each controller's private IPv4 for etcd usage
|
|
resource "aws_route53_record" "etcds" {
|
|
count = var.controller_count
|
|
|
|
# DNS Zone where record should be created
|
|
zone_id = var.dns_zone_id
|
|
|
|
name = format("%s-etcd%d.%s.", var.cluster_name, count.index, var.dns_zone)
|
|
type = "A"
|
|
ttl = 300
|
|
|
|
# private IPv4 address for etcd
|
|
records = [aws_instance.controllers.*.private_ip[count.index]]
|
|
}
|
|
|
|
# Controller instances
|
|
resource "aws_instance" "controllers" {
|
|
count = var.controller_count
|
|
|
|
tags = {
|
|
Name = "${var.cluster_name}-controller-${count.index}"
|
|
}
|
|
|
|
instance_type = var.controller_type
|
|
ami = var.arch == "arm64" ? data.aws_ami.fedora-coreos-arm[0].image_id : data.aws_ami.fedora-coreos.image_id
|
|
user_data = data.ct_config.controller-ignitions.*.rendered[count.index]
|
|
|
|
# storage
|
|
root_block_device {
|
|
volume_type = var.disk_type
|
|
volume_size = var.disk_size
|
|
iops = var.disk_iops
|
|
encrypted = true
|
|
}
|
|
|
|
# network
|
|
associate_public_ip_address = true
|
|
subnet_id = element(aws_subnet.public.*.id, count.index)
|
|
vpc_security_group_ids = [aws_security_group.controller.id]
|
|
|
|
lifecycle {
|
|
ignore_changes = [
|
|
ami,
|
|
user_data,
|
|
]
|
|
}
|
|
}
|
|
|
|
# Controller Ignition configs
|
|
data "ct_config" "controller-ignitions" {
|
|
count = var.controller_count
|
|
content = data.template_file.controller-configs.*.rendered[count.index]
|
|
strict = true
|
|
snippets = var.controller_snippets
|
|
}
|
|
|
|
# Controller Fedora CoreOS configs
|
|
data "template_file" "controller-configs" {
|
|
count = var.controller_count
|
|
|
|
template = file("${path.module}/fcc/controller.yaml")
|
|
|
|
vars = {
|
|
# Cannot use cyclic dependencies on controllers or their DNS records
|
|
etcd_arch = var.arch == "arm64" ? "-arm64" : ""
|
|
etcd_name = "etcd${count.index}"
|
|
etcd_domain = "${var.cluster_name}-etcd${count.index}.${var.dns_zone}"
|
|
# etcd0=https://cluster-etcd0.example.com,etcd1=https://cluster-etcd1.example.com,...
|
|
etcd_initial_cluster = join(",", data.template_file.etcds.*.rendered)
|
|
kubeconfig = indent(10, module.bootstrap.kubeconfig-kubelet)
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
cluster_dns_service_ip = cidrhost(var.service_cidr, 10)
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
}
|
|
}
|
|
|
|
data "template_file" "etcds" {
|
|
count = var.controller_count
|
|
template = "etcd$${index}=https://$${cluster_name}-etcd$${index}.$${dns_zone}:2380"
|
|
|
|
vars = {
|
|
index = count.index
|
|
cluster_name = var.cluster_name
|
|
dns_zone = var.dns_zone
|
|
}
|
|
}
|
|
|