mirror of
https://github.com/poseidon/typhoon
synced 2024-05-12 18:46:10 +02:00
256b87812e
* Use Terraform builtin templatefile functionality * Remove dependency on deprecated Terraform template provider Rel: * https://registry.terraform.io/providers/hashicorp/template/2.2.0 * https://github.com/poseidon/terraform-render-bootstrap/pull/293
85 lines
3.6 KiB
HCL
85 lines
3.6 KiB
HCL
locals {
|
|
remote_kernel = "https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-kernel-x86_64"
|
|
remote_initrd = [
|
|
"--name main https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-initramfs.x86_64.img",
|
|
]
|
|
|
|
remote_args = [
|
|
"initrd=main",
|
|
"coreos.live.rootfs_url=https://builds.coreos.fedoraproject.org/prod/streams/${var.os_stream}/builds/${var.os_version}/x86_64/fedora-coreos-${var.os_version}-live-rootfs.x86_64.img",
|
|
"coreos.inst.install_dev=${var.install_disk}",
|
|
"coreos.inst.ignition_url=${var.matchbox_http_endpoint}/ignition?uuid=$${uuid}&mac=$${mac:hexhyp}",
|
|
]
|
|
|
|
cached_kernel = "/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-kernel-x86_64"
|
|
cached_initrd = [
|
|
"/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-initramfs.x86_64.img",
|
|
]
|
|
|
|
cached_args = [
|
|
"initrd=main",
|
|
"coreos.live.rootfs_url=${var.matchbox_http_endpoint}/assets/fedora-coreos/fedora-coreos-${var.os_version}-live-rootfs.x86_64.img",
|
|
"coreos.inst.install_dev=${var.install_disk}",
|
|
"coreos.inst.ignition_url=${var.matchbox_http_endpoint}/ignition?uuid=$${uuid}&mac=$${mac:hexhyp}",
|
|
]
|
|
|
|
kernel = var.cached_install ? local.cached_kernel : local.remote_kernel
|
|
initrd = var.cached_install ? local.cached_initrd : local.remote_initrd
|
|
args = var.cached_install ? local.cached_args : local.remote_args
|
|
}
|
|
|
|
|
|
// Fedora CoreOS controller profile
|
|
resource "matchbox_profile" "controllers" {
|
|
count = length(var.controllers)
|
|
name = format("%s-controller-%s", var.cluster_name, var.controllers.*.name[count.index])
|
|
|
|
kernel = local.kernel
|
|
initrd = local.initrd
|
|
args = concat(local.args, var.kernel_args)
|
|
|
|
raw_ignition = data.ct_config.controllers.*.rendered[count.index]
|
|
}
|
|
|
|
# Fedora CoreOS controllers
|
|
data "ct_config" "controllers" {
|
|
count = var.controller_count
|
|
content = templatefile("${path.module}/fcc/controller.yaml", {
|
|
domain_name = var.controllers.*.domain[count.index]
|
|
etcd_name = var.controllers.*.name[count.index]
|
|
etcd_initial_cluster = join(",", formatlist("%s=https://%s:2380", var.controllers.*.name, var.controllers.*.domain))
|
|
cluster_dns_service_ip = module.bootstrap.cluster_dns_service_ip
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
})
|
|
strict = true
|
|
snippets = lookup(var.snippets, var.controllers.*.name[count.index], [])
|
|
}
|
|
|
|
// Fedora CoreOS worker profile
|
|
resource "matchbox_profile" "workers" {
|
|
count = length(var.workers)
|
|
name = format("%s-worker-%s", var.cluster_name, var.workers.*.name[count.index])
|
|
|
|
kernel = local.kernel
|
|
initrd = local.initrd
|
|
args = concat(local.args, var.kernel_args)
|
|
|
|
raw_ignition = data.ct_config.workers.*.rendered[count.index]
|
|
}
|
|
|
|
# Fedora CoreOS workers
|
|
data "ct_config" "workers" {
|
|
count = length(var.workers)
|
|
content = templatefile("${path.module}/fcc/worker.yaml", {
|
|
domain_name = var.workers.*.domain[count.index]
|
|
cluster_dns_service_ip = module.bootstrap.cluster_dns_service_ip
|
|
cluster_domain_suffix = var.cluster_domain_suffix
|
|
ssh_authorized_key = var.ssh_authorized_key
|
|
node_labels = join(",", lookup(var.worker_node_labels, var.workers.*.name[count.index], []))
|
|
node_taints = join(",", lookup(var.worker_node_taints, var.workers.*.name[count.index], []))
|
|
})
|
|
strict = true
|
|
snippets = lookup(var.snippets, var.workers.*.name[count.index], [])
|
|
}
|