mirror of
https://github.com/git/git.git
synced 2024-09-30 16:01:40 +02:00
b9dcf846e2
* commit 'git-gui/master': (36 commits) git-gui: Change prior tree SHA-1 verification to use git_read git-gui: Include a space in Cygwin shortcut command lines git-gui: Use sh.exe in Cygwin shortcuts git-gui: Paper bag fix for Cygwin shortcut creation git-gui: Improve the Windows and Mac OS X shortcut creators git-gui: Teach console widget to use git_read git-gui: Perform our own magic shbang detection on Windows git-gui: Treat `git version` as `git --version` git-gui: Assume unfound commands are known by git wrapper git-gui: Correct gitk installation location git-gui: Always use absolute path to all git executables git-gui: Show a progress meter for checking out files git-gui: Change the main window progress bar to use status_bar git-gui: Extract blame viewer status bar into mega-widget git-gui: Allow double-click in checkout dialog to start checkout git-gui: Default selection to first matching ref git-gui: Unabbreviate commit SHA-1s prior to display git-gui: Refactor branch switch to support detached head git-gui: Refactor our ui_status_value update technique git-gui: Better handling of detached HEAD ...
90 lines
2.0 KiB
Tcl
90 lines
2.0 KiB
Tcl
# git-gui branch checkout support
|
|
# Copyright (C) 2007 Shawn Pearce
|
|
|
|
class branch_checkout {
|
|
|
|
field w ; # widget path
|
|
field w_rev ; # mega-widget to pick the initial revision
|
|
|
|
field opt_fetch 1; # refetch tracking branch if used?
|
|
field opt_detach 0; # force a detached head case?
|
|
|
|
constructor dialog {} {
|
|
make_toplevel top w
|
|
wm title $top "[appname] ([reponame]): Checkout Branch"
|
|
if {$top ne {.}} {
|
|
wm geometry $top "+[winfo rootx .]+[winfo rooty .]"
|
|
}
|
|
|
|
label $w.header -text {Checkout Branch} -font font_uibold
|
|
pack $w.header -side top -fill x
|
|
|
|
frame $w.buttons
|
|
button $w.buttons.create -text Checkout \
|
|
-default active \
|
|
-command [cb _checkout]
|
|
pack $w.buttons.create -side right
|
|
button $w.buttons.cancel -text {Cancel} \
|
|
-command [list destroy $w]
|
|
pack $w.buttons.cancel -side right -padx 5
|
|
pack $w.buttons -side bottom -fill x -pady 10 -padx 10
|
|
|
|
set w_rev [::choose_rev::new $w.rev {Revision}]
|
|
$w_rev bind_listbox <Double-Button-1> [cb _checkout]
|
|
pack $w.rev -anchor nw -fill both -expand 1 -pady 5 -padx 5
|
|
|
|
labelframe $w.options -text {Options}
|
|
|
|
checkbutton $w.options.fetch \
|
|
-text {Fetch Tracking Branch} \
|
|
-variable @opt_fetch
|
|
pack $w.options.fetch -anchor nw
|
|
|
|
checkbutton $w.options.detach \
|
|
-text {Detach From Local Branch} \
|
|
-variable @opt_detach
|
|
pack $w.options.detach -anchor nw
|
|
|
|
pack $w.options -anchor nw -fill x -pady 5 -padx 5
|
|
|
|
bind $w <Visibility> [cb _visible]
|
|
bind $w <Key-Escape> [list destroy $w]
|
|
bind $w <Key-Return> [cb _checkout]\;break
|
|
tkwait window $w
|
|
}
|
|
|
|
method _checkout {} {
|
|
set spec [$w_rev get_tracking_branch]
|
|
if {$spec ne {} && $opt_fetch} {
|
|
set new {}
|
|
} elseif {[catch {set new [$w_rev commit_or_die]}]} {
|
|
return
|
|
}
|
|
|
|
if {$opt_detach} {
|
|
set ref {}
|
|
} else {
|
|
set ref [$w_rev get_local_branch]
|
|
}
|
|
|
|
set co [::checkout_op::new [$w_rev get] $new $ref]
|
|
$co parent $w
|
|
$co enable_checkout 1
|
|
if {$spec ne {} && $opt_fetch} {
|
|
$co enable_fetch $spec
|
|
}
|
|
|
|
if {[$co run]} {
|
|
destroy $w
|
|
} else {
|
|
$w_rev focus_filter
|
|
}
|
|
}
|
|
|
|
method _visible {} {
|
|
grab $w
|
|
$w_rev focus_filter
|
|
}
|
|
|
|
}
|