a9edb211e7
Before that '.log' files for scheme tests were fragmented and not included in test-suite.log. This unifies the semantics of SRFI-64 API with Automake test suite. * build-aux/test-driver.scm: New file. * Makefile.am (SCM_LOG_DRIVER, AM_SCM_LOG_DRIVER_FLAGS): New variables. (SCM_LOG_COMPILER, AM_SCM_LOG_FLAGS): Delete variables. (AM_TESTS_ENVIRONMENT): Set GUILE_AUTO_COMPILE to 0. * test-env.in: Silence guix-daemon. * doc/guix.texi (Running the Test Suite): Describe how to display the detailed results. Bug reports require only 'test-suite.log' file. * tests/base32.scm, tests/build-utils.scm, tests/builders.scm, tests/challenge.scm, tests/cpan.scm, tests/cpio.scm, tests/cran.scm, tests/cve.scm, tests/derivations.scm, tests/elpa.scm, tests/file-systems.scm, tests/gem.scm, tests/gexp.scm, tests/gnu-maintenance.scm, tests/grafts.scm, tests/graph.scm, tests/gremlin.scm, tests/hackage.scm, tests/hash.scm, tests/import-utils.scm, tests/lint.scm, tests/monads.scm, tests/nar.scm, tests/packages.scm, tests/pk-crypto.scm, tests/pki.scm, tests/profiles.scm, tests/publish.scm, tests/pypi.scm, tests/records.scm, tests/scripts-build.scm, tests/scripts.scm, tests/services.scm, tests/sets.scm, tests/size.scm, tests/snix.scm, tests/store.scm, tests/substitute.scm, tests/syscalls.scm, tests/system.scm, tests/ui.scm, tests/union.scm, tests/upstream.scm, tests/utils.scm: Don't exit at the end of test groups. * tests/containers.scm: Likewise. Use 'test-skip' instead of exiting with error code 77.
101 lines
3.2 KiB
Scheme
101 lines
3.2 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2015 Eric Bavier <bavier@member.fsf.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (test-cpan)
|
|
#:use-module (guix import cpan)
|
|
#:use-module (guix base32)
|
|
#:use-module (guix hash)
|
|
#:use-module (guix tests)
|
|
#:use-module (guix grafts)
|
|
#:use-module (srfi srfi-64)
|
|
#:use-module (ice-9 match))
|
|
|
|
;; Globally disable grafts because they can trigger early builds.
|
|
(%graft? #f)
|
|
|
|
(define test-json
|
|
"{
|
|
\"metadata\" : {
|
|
\"prereqs\" : {
|
|
\"runtime\" : {
|
|
\"requires\" : {
|
|
\"Test::Script\" : \"1.05\",
|
|
}
|
|
}
|
|
}
|
|
\"name\" : \"Foo-Bar\",
|
|
\"version\" : \"0.1\"
|
|
}
|
|
\"name\" : \"Foo-Bar-0.1\",
|
|
\"distribution\" : \"Foo-Bar\",
|
|
\"license\" : [
|
|
\"perl_5\"
|
|
],
|
|
\"abstract\" : \"Fizzle Fuzz\",
|
|
\"download_url\" : \"http://example.com/Foo-Bar-0.1.tar.gz\",
|
|
\"author\" : \"Guix\",
|
|
\"version\" : \"0.1\"
|
|
}")
|
|
|
|
(define test-source
|
|
"foobar")
|
|
|
|
(test-begin "cpan")
|
|
|
|
(test-assert "cpan->guix-package"
|
|
;; Replace network resources with sample data.
|
|
(mock ((guix build download) url-fetch
|
|
(lambda* (url file-name #:key (mirrors '()))
|
|
(with-output-to-file file-name
|
|
(lambda ()
|
|
(display
|
|
(match url
|
|
("http://api.metacpan.org/release/Foo-Bar"
|
|
test-json)
|
|
("http://api.metacpan.org/module/Test::Script"
|
|
"{ \"distribution\" : \"Test-Script\" }")
|
|
("http://example.com/Foo-Bar-0.1.tar.gz"
|
|
test-source)
|
|
(_ (error "Unexpected URL: " url))))))))
|
|
(match (cpan->guix-package "Foo::Bar")
|
|
(('package
|
|
('name "perl-foo-bar")
|
|
('version "0.1")
|
|
('source ('origin
|
|
('method 'url-fetch)
|
|
('uri ('string-append "http://example.com/Foo-Bar-"
|
|
'version ".tar.gz"))
|
|
('sha256
|
|
('base32
|
|
(? string? hash)))))
|
|
('build-system 'perl-build-system)
|
|
('inputs
|
|
('quasiquote
|
|
(("perl-test-script" ('unquote 'perl-test-script)))))
|
|
('home-page "http://search.cpan.org/dist/Foo-Bar")
|
|
('synopsis "Fizzle Fuzz")
|
|
('description 'fill-in-yourself!)
|
|
('license (package-license perl)))
|
|
(string=? (bytevector->nix-base32-string
|
|
(call-with-input-string test-source port-sha256))
|
|
hash))
|
|
(x
|
|
(pk 'fail x #f)))))
|
|
|
|
(test-end "cpan")
|