bdb36958fb
* gnu/packages/base.scm (gnu-make-boot0, diffutils-boot0,
findutils-boot0, %boot0-inputs, nix-system->gnu-triplet, boot-triplet,
binutils-boot0, gcc-boot0, perl-boot0, linux-libre-headers-boot0,
texinfo-boot0, %boot1-inputs, glibc-final-with-bootstrap-bash,
cross-gcc-wrapper, static-bash-for-glibc, glibc-final,
gcc-boot0-wrapped, %boot2-inputs, binutils-final, libstdc++,
gcc-final, ld-wrapper-boot3, %boot3-inputs, bash-final, %boot4-inputs,
guile-final, gnu-make-final, ld-wrapper, coreutils-final, grep-final,
%boot5-inputs, %final-inputs, canonical-package, gcc-toolchain,
gcc-toolchain-4.8, gcc-toolchain-4.9): Move to...
* gnu/packages/commencement.scm: ... here. New file.
* gnu-system.am (GNU_SYSTEM_MODULES): Add it.
* build-aux/check-final-inputs-self-contained.scm: Adjust accordingly.
* gnu/packages/cross-base.scm: Likewise.
* gnu/packages/make-bootstrap.scm: Likewise.
* guix/build-system/cmake.scm (cmake-build): Likewise.
* guix/build-system/gnu.scm (standard-packages, gnu-build,
gnu-cross-build): Likewise.
* guix/build-system/perl.scm (perl-build): Likewise.
* guix/build-system/python.scm (python-build): Likewise.
* guix/build-system/trivial.scm (guile-for-build): Likewise.
* guix/download.scm (url-fetch): Likewise.
* guix/gexp.scm (default-guile): Likewise.
* guix/git-download.scm (git-fetch): Likewise.
* guix/monads.scm (run-with-store): Likewise.
* guix/packages.scm (default-guile): Likewise.
* guix/scripts/package.scm (guix-package): Likewise.
* guix/scripts/refresh.scm: Likewise.
* guix/svn-download.scm (svn-fetch): Likewise.
* tests/builders.scm (%bootstrap-inputs, %bootstrap-search-paths):
Likewise.
* tests/packages.scm ("GNU Make, bootstrap"): Likewise.
* tests/guix-package.sh: Likewise.
* gnu/services/base.scm: Use 'canonical-package' instead of xxx-final.
* gnu/services/xorg.scm: Likewise.
* gnu/system/vm.scm: Likewise.
* guix/scripts/pull.scm (guix-pull): Likewise.
113 lines
4.0 KiB
Scheme
113 lines
4.0 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2014 Ludovic Courtès <ludo@gnu.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (guix git-download)
|
|
#:use-module (guix gexp)
|
|
#:use-module (guix monads)
|
|
#:use-module (guix records)
|
|
#:use-module (guix packages)
|
|
#:autoload (guix build-system gnu) (standard-inputs)
|
|
#:use-module (ice-9 match)
|
|
#:export (git-reference
|
|
git-reference?
|
|
git-reference-url
|
|
git-reference-commit
|
|
git-reference-recursive?
|
|
|
|
git-fetch))
|
|
|
|
;;; Commentary:
|
|
;;;
|
|
;;; An <origin> method that fetches a specific commit from a Git repository.
|
|
;;; The repository URL and commit hash are specified with a <git-reference>
|
|
;;; object.
|
|
;;;
|
|
;;; Code:
|
|
|
|
(define-record-type* <git-reference>
|
|
git-reference make-git-reference
|
|
git-reference?
|
|
(url git-reference-url)
|
|
(commit git-reference-commit)
|
|
(recursive? git-reference-recursive? ; whether to recurse into sub-modules
|
|
(default #f)))
|
|
|
|
(define (git-package)
|
|
"Return the default Git package."
|
|
(let ((distro (resolve-interface '(gnu packages version-control))))
|
|
(module-ref distro 'git)))
|
|
|
|
(define* (git-fetch store ref hash-algo hash
|
|
#:optional name
|
|
#:key (system (%current-system)) guile
|
|
(git (git-package)))
|
|
"Return a fixed-output derivation in STORE that fetches REF, a
|
|
<git-reference> object. The output is expected to have recursive hash HASH of
|
|
type HASH-ALGO (a symbol). Use NAME as the file name, or a generic name if
|
|
#f."
|
|
(define guile-for-build
|
|
(match guile
|
|
((? package?)
|
|
(package-derivation store guile system))
|
|
(#f ; the default
|
|
(let* ((distro (resolve-interface '(gnu packages commencement)))
|
|
(guile (module-ref distro 'guile-final)))
|
|
(package-derivation store guile system)))))
|
|
|
|
(define inputs
|
|
;; When doing 'git clone --recursive', we need sed, grep, etc. to be
|
|
;; available so that 'git submodule' works.
|
|
(if (git-reference-recursive? ref)
|
|
(standard-inputs (%current-system))
|
|
'()))
|
|
|
|
(define build
|
|
#~(begin
|
|
(use-modules (guix build git)
|
|
(guix build utils)
|
|
(ice-9 match))
|
|
|
|
;; The 'git submodule' commands expects Coreutils, sed,
|
|
;; grep, etc. to be in $PATH.
|
|
(set-path-environment-variable "PATH" '("bin")
|
|
(match '#$inputs
|
|
(((names dirs) ...)
|
|
dirs)))
|
|
|
|
(git-fetch '#$(git-reference-url ref)
|
|
'#$(git-reference-commit ref)
|
|
#$output
|
|
#:recursive? '#$(git-reference-recursive? ref)
|
|
#:git-command (string-append #$git "/bin/git"))))
|
|
|
|
(run-with-store store
|
|
(gexp->derivation (or name "git-checkout") build
|
|
#:system system
|
|
#:local-build? #t
|
|
#:hash-algo hash-algo
|
|
#:hash hash
|
|
#:recursive? #t
|
|
#:modules '((guix build git)
|
|
(guix build utils))
|
|
#:guile-for-build guile-for-build
|
|
#:local-build? #t)
|
|
#:guile-for-build guile-for-build
|
|
#:system system))
|
|
|
|
;;; git-download.scm ends here
|