88981dd3e2
* guix/ui.scm: Add missing copyright lines. (args-fold*, environment-build-options, %default-argument-handler, parse-command-line): Move to ... * guix/scripts.scm: ...here. New file. * guix/scripts/archive.scm: Use it. * guix/scripts/build.scm: Likewise. * guix/scripts/download.scm: Likewise. * guix/scripts/edit.scm: Likewise. * guix/scripts/environment.scm: Likewise. * guix/scripts/gc.scm: Likewise. * guix/scripts/graph.scm: Likewise. * guix/scripts/hash.scm: Likewise. * guix/scripts/import/cpan.scm: Likewise. * guix/scripts/import/cran.scm: Likewise. * guix/scripts/import/elpa.scm: Likewise. * guix/scripts/import/gem.scm: Likewise. * guix/scripts/import/gnu.scm: Likewise. * guix/scripts/import/hackage.scm: Likewise. * guix/scripts/import/nix.scm: Likewise. * guix/scripts/import/pypi.scm: Likewise. * guix/scripts/lint.scm: Likewise. * guix/scripts/package.scm: Likewise. * guix/scripts/publish.scm: Likewise. * guix/scripts/pull.scm: Likewise. * guix/scripts/refresh.scm: Likewise. * guix/scripts/size.scm: Likewise. * guix/scripts/system.scm: Likewise. * tests/ui.scm (with-environment-variable, "parse-command-line", "parse-command-line and --no options"): Move to ... * tests/scripts.scm: ...here. New file. * Makefile.am (MODULES): Add guix/scripts.scm. (SCM_TESTS): Add tests/scripts.scm. * po/guix/POTFILES.in: Add guix/scripts.scm.
81 lines
3.0 KiB
Scheme
81 lines
3.0 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2015 Ludovic Courtès <ludo@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (guix scripts edit)
|
||
#:use-module (guix ui)
|
||
#:use-module (guix scripts)
|
||
#:use-module (guix utils)
|
||
#:use-module (guix packages)
|
||
#:use-module (gnu packages)
|
||
#:use-module (srfi srfi-1)
|
||
#:use-module (srfi srfi-37)
|
||
#:export (%editor
|
||
guix-edit))
|
||
|
||
(define %options
|
||
(list (option '(#\h "help") #f #f
|
||
(lambda args
|
||
(show-help)
|
||
(exit 0)))
|
||
(option '(#\V "version") #f #f
|
||
(lambda args
|
||
(show-version-and-exit "guix edit")))))
|
||
|
||
(define (show-help)
|
||
(display (_ "Usage: guix edit PACKAGE...
|
||
Start $EDITOR to edit the definitions of PACKAGE...\n"))
|
||
(newline)
|
||
(display (_ "
|
||
-h, --help display this help and exit"))
|
||
(display (_ "
|
||
-V, --version display version information and exit"))
|
||
(newline)
|
||
(show-bug-report-information))
|
||
|
||
(define %editor
|
||
(make-parameter (or (getenv "EDITOR") "emacsclient")))
|
||
|
||
(define (search-path* path file)
|
||
"Like 'search-path' but exit if FILE is not found."
|
||
(let ((absolute-file-name (search-path path file)))
|
||
(unless absolute-file-name
|
||
;; Shouldn't happen unless somebody fiddled with the 'location' field.
|
||
(leave (_ "file '~a' not found in search path ~s~%")
|
||
file path))
|
||
absolute-file-name))
|
||
|
||
|
||
(define (guix-edit . args)
|
||
(with-error-handling
|
||
(let* ((specs (parse-command-line args %options '(())
|
||
#:argument-handler cons))
|
||
(packages (map specification->package specs)))
|
||
(for-each (lambda (package)
|
||
(unless (package-location package)
|
||
(leave (_ "source location of package '~a' is unknown~%")
|
||
(package-full-name package))))
|
||
packages)
|
||
(apply execlp (%editor) (%editor)
|
||
(append-map (lambda (package)
|
||
(let ((loc (package-location package)))
|
||
(list (string-append "+"
|
||
(number->string
|
||
(location-line loc)))
|
||
(search-path* %load-path (location-file loc)))))
|
||
packages)))))
|