462f5ccade
Suggested by Alex Kost <alezost@gmail.com>.
* guix/scripts/package.scm (options->installable)[package->manifest-entry]:
Move to (guix profiles).
[package->manifest-entry*]: New procedure.
Use it.
* guix/profiles.scm (package->manifest-entry): New procedure.
* tests/profiles.scm (guile-for-build): New variable.
Call '%guile-for-build'.
("profile-derivation"): New test.
125 lines
4.6 KiB
Scheme
125 lines
4.6 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
||
;;; Copyright © 2013, 2014 Ludovic Courtès <ludo@gnu.org>
|
||
;;;
|
||
;;; This file is part of GNU Guix.
|
||
;;;
|
||
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
||
;;; under the terms of the GNU General Public License as published by
|
||
;;; the Free Software Foundation; either version 3 of the License, or (at
|
||
;;; your option) any later version.
|
||
;;;
|
||
;;; GNU Guix is distributed in the hope that it will be useful, but
|
||
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;;; GNU General Public License for more details.
|
||
;;;
|
||
;;; You should have received a copy of the GNU General Public License
|
||
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
(define-module (test-profiles)
|
||
#:use-module (guix profiles)
|
||
#:use-module (guix store)
|
||
#:use-module (guix monads)
|
||
#:use-module (guix packages)
|
||
#:use-module (guix derivations)
|
||
#:use-module (gnu packages bootstrap)
|
||
#:use-module (ice-9 match)
|
||
#:use-module (srfi srfi-64))
|
||
|
||
;; Test the (guix profile) module.
|
||
|
||
(define %store
|
||
(open-connection))
|
||
|
||
(define guile-for-build
|
||
(package-derivation %store %bootstrap-guile))
|
||
|
||
;; Make it the default.
|
||
(%guile-for-build guile-for-build)
|
||
|
||
|
||
;; Example manifest entries.
|
||
|
||
(define guile-2.0.9
|
||
(manifest-entry
|
||
(name "guile")
|
||
(version "2.0.9")
|
||
(item "/gnu/store/...")
|
||
(output "out")))
|
||
|
||
(define guile-2.0.9:debug
|
||
(manifest-entry (inherit guile-2.0.9)
|
||
(output "debug")))
|
||
|
||
|
||
(test-begin "profiles")
|
||
|
||
(test-assert "manifest-installed?"
|
||
(let ((m (manifest (list guile-2.0.9 guile-2.0.9:debug))))
|
||
(and (manifest-installed? m (manifest-pattern (name "guile")))
|
||
(manifest-installed? m (manifest-pattern
|
||
(name "guile") (output "debug")))
|
||
(manifest-installed? m (manifest-pattern
|
||
(name "guile") (output "out")
|
||
(version "2.0.9")))
|
||
(not (manifest-installed?
|
||
m (manifest-pattern (name "guile") (version "1.8.8"))))
|
||
(not (manifest-installed?
|
||
m (manifest-pattern (name "guile") (output "foobar")))))))
|
||
|
||
(test-assert "manifest-matching-entries"
|
||
(let* ((e (list guile-2.0.9 guile-2.0.9:debug))
|
||
(m (manifest e)))
|
||
(and (null? (manifest-matching-entries m
|
||
(list (manifest-pattern
|
||
(name "python")))))
|
||
(equal? e
|
||
(manifest-matching-entries m
|
||
(list (manifest-pattern
|
||
(name "guile")
|
||
(output #f)))))
|
||
(equal? (list guile-2.0.9)
|
||
(manifest-matching-entries m
|
||
(list (manifest-pattern
|
||
(name "guile")
|
||
(version "2.0.9"))))))))
|
||
|
||
(test-assert "manifest-remove"
|
||
(let* ((m0 (manifest (list guile-2.0.9 guile-2.0.9:debug)))
|
||
(m1 (manifest-remove m0
|
||
(list (manifest-pattern (name "guile")))))
|
||
(m2 (manifest-remove m1
|
||
(list (manifest-pattern (name "guile"))))) ; same
|
||
(m3 (manifest-remove m2
|
||
(list (manifest-pattern
|
||
(name "guile") (output "debug")))))
|
||
(m4 (manifest-remove m3
|
||
(list (manifest-pattern (name "guile"))))))
|
||
(match (manifest-entries m2)
|
||
((($ <manifest-entry> "guile" "2.0.9" "debug"))
|
||
(and (equal? m1 m2)
|
||
(null? (manifest-entries m3))
|
||
(null? (manifest-entries m4)))))))
|
||
|
||
(test-assert "profile-derivation"
|
||
(run-with-store %store
|
||
(mlet* %store-monad
|
||
((entry -> (package->manifest-entry %bootstrap-guile))
|
||
(guile (package->derivation %bootstrap-guile))
|
||
(drv (profile-derivation (manifest (list entry))))
|
||
(profile -> (derivation->output-path drv))
|
||
(bindir -> (string-append profile "/bin"))
|
||
(_ (built-derivations (list drv))))
|
||
(return (and (file-exists? (string-append bindir "/guile"))
|
||
(string=? (dirname (readlink bindir))
|
||
(derivation->output-path guile)))))))
|
||
|
||
(test-end "profiles")
|
||
|
||
|
||
(exit (= (test-runner-fail-count (test-runner-current)) 0))
|
||
|
||
;;; Local Variables:
|
||
;;; eval: (put 'dummy-package 'scheme-indent-function 1)
|
||
;;; End:
|